Прозрачный цвет в StringGrid

Я заполняю ячейки в зеленом цвете StringGrid

procedure TForm1.StringGridDrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin

StringGrid.Canvas.Brush.Color := clGreen;
StringGrid.Canvas.FillRect(Rect);

StringGrid.Canvas.TextOut(Rect.Left + 2, Rect.Top + 2, AGrid.Cells[ACol, ARow]);

end;

Мой StringGrid имеет черный цвет. Я хотел бы заполнить прозрачный цвет ячейки (например, 50%).

Как я могу это сделать?

Я должен рисовать прямоугольник? Или я должен создать растровое изображение и положить в ячейку?

Вы можете мне помочь?:)

Эффект Imean: введите описание изображения здесь

delphi,pascal,lazarus,freepascal,stringgrid,

0

Ответов: 1


5 принят

С вдохновением от этого поста я сначала создал TStringGridизображение с фоном. Затем я добавил прозрачный цвет WinApi.Windows.AlphaBlend()для выбранных ячеек и аналогично для фиксированных ячеек. Конечным результатом является следующее:

введите описание изображения здесь

Прозрачный «выбранный» цвет выполнен в виде 1-битового растрового изображения:

type
  TStringGrid = class(Vcl.Grids.TStringGrid)
  private
    FBackG: TBitmap;
    FForeG: TBitmap;
  ...

procedure TForm5.Button1Click(Sender: TObject);
begin
  sg.FForeG.Free;
  sg.FForeG := TBitmap.Create;
  sg.FForeG.SetSize(1, 1);
  sg.FForeG.PixelFormat := pf32bit;
  sg.FForeG.Canvas.Pixels[0, 0] := $00FF00;  // BGR
end;

И битмап применяется для «выбранных» ячеек ( gdSelected in State) в OnDrawCellсобытии

procedure TForm5.sgDrawCell(Sender: TObject; ACol, ARow: Integer; Rect: TRect;
  State: TGridDrawState);
var
  sg: TStringGrid;
  r: TRect;
  success:boolean;
begin
  if not (Sender is TStringGrid) then Exit;
  sg := Sender as TStringGrid;

  r := Rect;
  r.Left := r.Left-4; // Might not be needed, depending on Delphi version?

  // Clear the cell
  sg.Canvas.Brush.Color := clBlack;
  sg.Canvas.FillRect(r);

  // Copy background to cell
  BitBlt(sg.Canvas.Handle,
    r.Left, r.Top, r.Right - r.Left, r.Bottom - r.Top,
    sg.FBackG.Canvas.Handle, r.Left, r.Top, SRCCOPY);

    // Draw fixed column or row cell(s)
  if gdFixed in State then
  begin
    success := Winapi.Windows.AlphaBlend(sg.Canvas.Handle,
      r.Left, r.Top, r.Right - r.Left, r.Bottom - r.Top,
      sg.FHeadG.Canvas.Handle, 0, 0, 1, 23, BlendFunc);
  end;

  // Draw selected cell(s)
  if gdSelected in State then
  begin
    success := Winapi.Windows.AlphaBlend(sg.Canvas.Handle,
      r.Left, r.Top, r.Right - r.Left, r.Bottom - r.Top,
      sg.FForeG.Canvas.Handle, 0, 0, 1, 1, BlendFunc);
  end;

  // Draw the text
  r := Rect;
  sg.Canvas.Brush.Style := bsClear;
  DrawText(sg.Canvas.Handle, sg.Cells[ACol, ARow],
    length(sg.Cells[ACol, ARow]), r,
    DT_SINGLELINE or DT_VCENTER or DT_END_ELLIPSIS);
end;

BlendFunc: _BLENDFUNCTION;Структура может быть объявлена в TStringGridподклассе или в другом месте , где он доступен, я объявил его в форме и инициализируюсь его в формах OnCreateсобытии:

  BlendFunc.BlendOp := AC_SRC_OVER;
  BlendFunc.BlendFlags := 0;
  BlendFunc.SourceConstantAlpha := 128;  // This determines opacity
  BlendFunc.AlphaFormat := AC_SRC_ALPHA;

Теперь вы можете спросить, как работает 1-пиксельное растровое изображение, и ответ находится в документации для AlphaBlend():

Если исходный прямоугольник и прямоугольник назначения не имеют одинаковый размер, исходная растровая карта растягивается в соответствии с прямоугольником назначения.

Это полезно, поскольку прямоугольники ячеек обычно различаются по размеру.

Строка заголовка и столбец аналогично отображаются в OnDrawCellсостоянии on, if gdFixed in Stateи здесь используется другое растровое изображение. Это 1-пиксельная широкоформатная и 23-пиксельная высокая растровая карта, которую я сделал отдельно в программе графического рисования.

введите описание изображения здесь

Да! Крошечная вещь выше - изображение.

Дельфы, паскаль, Lazarus, FreePascal, StringGrid,
Похожие вопросы